SIOC "IF" Question

[deering]

___________________

[Boeing 747 Flyer]

Meh. I tried.

I really boils my water when people act like you have throughout this thread. Please do not repeat this pathetic behaviour again.

If I were a teacher, I would applaud a student's enthuasiasm. You have done the complete opposite; which, quite frankly, is disgusting.

[Boeing 747 Flyer]

If anyone's interested, I finally figured out how to do it.

Through use of a Subroutine as a "checker", at 12:15AM last night all pulled through.

Script:

Var 9888, Link FSUIPC_IN, Offset $C28D, Length 1 // Cloud Precipitation Rate (1)
{
  IF v9888 >= 3
 { 
&REF = 0
   &BlinkLed = 500000 // Begin value of timer
   &BlinkLed = TIMER 0 -1 40
 }
}
   
Var 9891, name BlinkLed
{
    L0 = MOD &BlinkLed 2
 IF L0 = 0
 {
     &REF = 0
 }
   ELSE
  {
     &REF = 1
  }
}

Var 7675, name REF, Link IOCARD_OUT, Output 4 // REF LED
{
IF &REF = 0
 {
CALL &PRECIPTEST
 }
}

Var 9105, name PRECIPSET, Link SUBRUTINE
{
 IF v9888 > 0
 {
 IF v9888 < 3 // YEH
  {
  &REF = 1
  }
 }
}



Var 9887, Link FSUIPC_IN, Offset $C28D, Length 1 // Cloud Precipitation Rate (1)
{
  IF v9887 < 3
 { 
   &BlinkLed = 1 // equal to end value of timer (0) + 1
   &REF = 1
 }
}

Var 9886, Link FSUIPC_IN, Offset $C28D, Length 1 // Cloud Precipitation Rate (1)
{
  IF v9886 = 0
 { 
&REF = 0
 }
}

Nico Kaan has also suggested another method for me to use. I am currently experimenting with both to see which is the more efficient.

[kiek]

Hi Jack,

Just a few tips, to help you. In my (humble) opinion there are several things "wrong" with your script:

* You defined three variables linked to the same FSUIPC offset, which is not efficient and can lead to "race-conditions". E.g. if the FSUIPC offset becomes 0, Var 9887 is executed and &REF will be set to 1, while "concurrently" Var 9886 is executed and that code will try to set &REF to 0 ..... It is just because you have defined Var 9887 just before Var 9886 that it this time works, but if Opencockpits changes the order of evaluation from forwards to backwards your in trouble ... So never program like this. Always put all sioc code related to a FSUIPC offset in one Variable.

* It is also bad programming practice to attach sioc code to an output definition (Var 7675). If one writes to an output one assumes it will go to the output, not that an attached sioc statement changes the value that you just wrote .... E.g I write 0 to that output, but due to the CALL to PRECIPTEST it might be overwritten by the value 1... (UGLY )

* If precip becomes 3 you start a timer (in Var 988 . However, if precip becomes 4 you start another timer, (same with 5, and so on). This is not efficient and the outcome becomes undefined.

Maybe it is better to move over to my code:

Note that it is important keep status of whether the led is already blinking because you have to take into account whether you are going up or down in precip value ...

Var 9000 name blinking value 0   // 0 or 1 (blinking)
Var 9001 name precip link FSUIPC_IN offset $C28D length 1
{
  IF &precip = 0
  {
    &REF = 0
  }
  ELSE
  {
    C0 = &precip = 1
    C1 = &precip = 2
    IF C0 OR C1
    {
      &REF = 1
    }
    ELSE
    {
      IF &precip = 3
      {
        if &blinking = 1
        {
           &blinking = 0
           &blinkLed = 1   // coming from 4, stop blinking
        }
        ELSE
        {
          &REF = 1   // coming from 2, keep led on ...
        }
      }
      ELSE
      {
        if &blinking = 0
        {
          &blinking = 1
          &blinkLed = 500000 
          &blinkLed = TIMER 0 -1 40
        }
      }
    }
  }
}

Var 9002 name blinkLed
{
  // make sure that blinking stops with led = On,
  // end value of TIMER has to be even.
  L0 = MOD &Blinkled 2
  IF L0 = 0
  {
    &REF = 1
  }
  ELSE
  {
    &REF = 0
  }
}
Var 9003 name REF Link IOCARD_OUT Output 93

[Boeing 747 Flyer]

Hi Nico,

Not sure what I've done wrong, but I can't get your script to work. Basically, the LED goes ON and OFF as it should, but never BLINKS. I think this lies within Var "Blinking". The LED will only blink if this Var is =1, but I don't know how it becomes =1?

Script:

Var 9003, name REF, Link IOCARD_OUT, Output 93
Var 9000, name Blinking, Value 0 // 0 or 1 (Blinking)
Var 9001, name precip, link FSUIPC_IN, Offset $C28D, Length 1 //  Cloud Precipitation Rate (1)
{
  IF &Precip = 0
  {
    &REF = 0
  }
  ELSE
  {
    C0 = &Precip = 1
    C1 = &Precip = 2
    IF C0 OR C1
    {
      &REF = 1
    }
    ELSE
    {
      IF &Precip >= 3
      {
        if &Blinking = 1
        {
           &Blinking = 0
           &BlinkLed = 1   // coming from 4, stop blinking
        }
        ELSE
        {
          &REF = 1   // coming from 2, keep led on ...
        }
      }
      ELSE
      {
        if &blinking = 0
        {
          &Blinking = 1
          &BlinkLed = 500000 
          &BlinkLed = TIMER 0 -1 40
        }
      }
    }
  }
}

Var 9002, name BlinkLed
{
  L0 = MOD &Blinkled 2
  IF L0 = 0
  {
    &REF = 1
  }
  ELSE
  {
    &REF = 0
  }
}

[kiek]

Is precip ever 4 ? I assumed it is, otherwise I have to change the script

[Boeing 747 Flyer]

Is precip ever 4 ? I assumed it is, otherwise I have to change the script

Hi Nico,

Precip can be anything 0-5.

[kiek]

Okaty, try this script:

Var 9000, name Blinking, Value 0 // 0 or 1 (Blinking)

Var 9001, name precip, link FSUIPC_IN, Offset $C28D, Length 1 //  Cloud Precipitation Rate (1)
{
  IF &precip = 0
  {
    &REF = 0
  }
  ELSE
  {
    IF &precip = 1
    {
      &REF = 1
    }
    ELSE
    {
      If &precip = 2
      {
        if &Blinking = 1
        {
           &Blinking = 0
           &BlinkLed = 1   // coming from 3, stop blinking
        }
      }
      ELSE
      {
        IF &precip = 3
        {
          IF &blinking = 0   // coming from 2
          {
            &Blinking = 1
            &BlinkLed = 500000 
            &BlinkLed = TIMER 0 -1 40
          }
        }
      }
    }
  }
}

Var 9002, name BlinkLed
{
  L0 = MOD &Blinkled 2
  IF L0 = 0
  {
    &REF = 1
  }
  ELSE
  {
    &REF = 0
  }
}

Var 9003, name REF, Link IOCARD_OUT, Output 93

Nico

[Boeing 747 Flyer]

Hi Nico,

I am facing similar problems. Basically, I've had a look at the Script, and I (think) there are some errors:

- If 0, LED is OFF
- If 1,2 LED is ON
- If 3, 4, 5 LED BLINKS

I think there are parts of the code which do not achieve this?

Thanks very much,

Jack

[kiek]

Jack,
Can you be more specific

Hi Nico,

there are some errors:

- If 0, LED is OFF
- If 1,2 LED is ON
- If 3, 4, 5 LED BLINKS

What do you mean by this: a specification? or is it what you see (which is according to my spec), so why do you speak about Errors?

What exactly do you think is missing?
How do you check this script?

Nico